세계의끝과 플래시 원더랜드

package kr.ufx.utils
{
	import kr.ufx.text.replaceString;
 
	/**
	 * ...
	 * @author 원종선(세계의끝) http://ufx.kr/blog
	 */
	public class OptimizeXMLString
	{
		// 찾을 문자열
		private var _arrStringList:Array = [ "\r\n", "\t", "%26" ];
 
		// 바꿔낼 문자열
		private var _arrReplacedList:Array = [ "\n", "", "&" ];
 
		private var _text:String;
 
		public function OptimizeXMLString( $text:String = null )
		{
			this._text = $text;
		}
 
		public function addReplace( $string:String, $replaced:String ):void
		{
			_arrStringList.push( $string );
			_arrReplacedList.push( $replaced );
		}
 
		public function optimizing( $text:String = null ):String
		{
			var str:String = getText( $text );
 
			var len:uint = _arrStringList.length;
			for ( var i:uint = 0; i < len; ++i )
			{
				str = replaceString( str, _arrStringList[ i ], _arrReplacedList[ i ] )
			}
			return str;
		}
 
		private function getText( $text:String ):String
		{
			var str:String;
 
			if ( $text )
				str = _text = $text;
 
			else if ( _text )
				str = _text;
 
			else
				str = "";
 
			return str;
		}
 
 
		public function get stringList():Array { return _arrStringList; }
 
		public function get replacedList():Array { return _arrReplacedList; }
 
		public function get text():String { return _text; }
 
		public function set text( $value:String ):void 
		{
			_text = $value;
		}
	}
}

import kr.ufx.utils.OptimizeXMLString;
 
var str:String = "세계의끝 %26 플래시 %26 원더랜드";
trace( str );
// 출력 : 세계의끝 %26 플래시 %26 원더랜드
 
// 생성자에서 변환할 text 대입
var optimizer:OptimizeXMLString = new OptimizeXMLString( str );
trace( optimizer.optimizing() );
// 출력 : 세계의끝 & 플래시 & 원더랜드
 
// optimizing 메서드에 직접 text 를 대입하여 변경
trace( optimizer.optimizing( "2001 %26 스페이스 %26 오딧세이" ) );
// 출력 : 2001 & 스페이스 & 오딧세이
 
// getter 메서드를 이용해 text 대입 ( text 내용 변경 )
optimizer.text = "시계태엽 %26 오렌지";
trace( optimizer.optimizing() );
// 출력 : 시계태엽 & 오렌지
 
// 변환할 단어를 추가
optimizer.addReplace( "오렌지", "어린쥐" );
trace( optimizer.optimizing() );
// 출력 : 시계태엽 & 어린쥐