package
{
	public class SuperClass
	{
		protected function doSomething():void
		{
			trace( "SuperClass 에서 실행된 doSomething()" );
		}
	}
}

package
{
	public class SubClass extends SuperClass
	{
		public function SubClass()
		{
			// SuperClass 의 protected 메서드 호출가능
			doSomething();
		}
	}
}

package
{
	public class SuperClass
	{
		public function SuperClass()
		{
			// 호출 불가 !!
			doSomething();
		}
	}
}

package
{
	public class SubClass extends SuperClass
	{
		protected function doSomething():void
		{
			trace( "SubClass 에서 실행된 doSomething()" );
		}
	}
}

package
{
	public class SuperClass
	{
		public function SuperClass()
		{
			doSomething();
		}
 
		protected function doSomething():void
		{
			throw new Error( "이런 이런~ doSomething() 메서드를 override 하는걸 까먹었군요!!" )
		}
	}
}

package
{
	public class SubClass extends SuperClass
	{
		override protected function doSomething():void
		{
			trace( "SubClass 에서 호출된 doSomething()" );
		}
	}
}

package
{
	import flash.display.Sprite;
	import flash.events.Event;
	import flash.events.MouseEvent;
	import flash.filters.BitmapFilter;
 
	public class Item extends Sprite
	{
		protected var _filterList:Array = [];
		protected var _filter:BitmapFilter;
 
		public function Item( $color:uint )
		{
			// 클릭을 위한 RoundRect 그리기
			// 그림 그리기, 이벤트리스너는 공통이므로 상위 클래스에서 처리
			this.graphics.beginFill( $color );
			this.graphics.drawRoundRect( 0, 0, 100, 100, 60 );
 
			this.buttonMode = true;
			this.addEventListener( MouseEvent.ROLL_OVER, rollOverHandler );
			this.addEventListener( MouseEvent.ROLL_OUT, rollOutHandler );
		}
 
		private function rollOverHandler( $e:MouseEvent ):void
		{
			// 공통적인 로직은 상위 클래스에서 처리.
			filters = _filterList;
 
			// 개별적인 로직을 처리하기 위한 메서드를 실행.
			rollOverForm();
 
			// 이렇게 이 객체를 addChild 한 부모 객체가 수신할 수 있도록 dispatchEvent() 하면서
			// 커스텀 이벤트를 이용해 이 Item 객체 내부에 있는 필터 객체를 보냄
			this.dispatchEvent( new CustomEvent( CustomEvent.CALL, { filterObject: this._filter } ) );
		}
 
		private function rollOutHandler( $e:MouseEvent ):void
		{
			filters = [];
			rollOutForm();
		}
 
		/**
		 * 하위 클래스 에서 override 해야 하는 메서드.
		 * protected 로 선언되어 있음
		 */
		protected function rollOverForm():void
		{
			throw new Error( "이런 이런~ addFilter() 메서드를 override 하는걸 까먹었군요!!" )
		}
 
		protected function rollOutForm():void
		{
			throw new Error( "이런 이런~ removeFilter() 메서드를 override 하는걸 까먹었군요!!" )
		}
	}
}

package
{
	import flash.filters.BlurFilter;
	import flash.filters.GlowFilter;
 
	public class GlowItem extends Item
	{
		private var _rollOutFilterList:Array = [];
		private var _blurFilter:BlurFilter;
 
		public function GlowItem( $color:uint )
		{
			super( $color );
			_filter = new GlowFilter( 0x6699FF, 1, 20, 20 );
			_filterList.push( _filter );
 
			_blurFilter = new BlurFilter( 20, 0 );
			_rollOutFilterList.push( _blurFilter );
			rollOutForm();
		}
 
		override protected function rollOverForm():void
		{
			// 여긴 딱히 할일이 없군요.
		}
 
		override protected function rollOutForm():void
		{
			// 이 클래스는 롤아웃 상태에서 블러 필터를 적용한다는 설정
			filters = _rollOutFilterList;
		}
	}
}

package
{
	import flash.filters.DropShadowFilter;
 
	public class DropShadowItem extends Item
	{
		public function DropShadowItem( $color:uint )
		{
			super( $color );
			alpha = 0.5;
			_filter = new DropShadowFilter( 5, 45, 0x000000, 0.7, 5, 5 );
			_filterList.push( _filter );
		}
 
		override protected function rollOverForm():void
		{
			// 이 클래스는 GlowItem 클래스와는 달리 alpha 속성을 함께 변경한다는 설정
			alpha = 1;
		}
 
		override protected function rollOutForm():void
		{
			alpha = 0.5;
		}
	}
}

package
{
	import flash.display.Sprite;
 
	[SWF ( width = 440, height = 160, frameRate = 30, backgroundColor = 0xE3E3E3 ) ]
 
	public class DocumentClass extends Sprite
	{
 
		public function DocumentClass()
		{
			var item1:Item = new GlowItem( 0x336699 );
			with ( addChild( item1 ) )
			{
				name = "item1";
				x = 100;
				y = 30;
				addEventListener( CustomEvent.CALL, callHandler );
			}
 
			var item2:Item = new DropShadowItem( 0x008FCC );
			with ( addChild( item2 ) )
			{
				name = "item2";
				x = 240;
				y = 30;
				addEventListener( CustomEvent.CALL, callHandler );
			}
		}
 
		private function callHandler( $e:CustomEvent ):void
		{
			trace( $e.currentTarget.name, "filterObject:", $e.data.filterObject );
		}
	}
}