AS3.0 로더(Loader)로 불러온 다른 swf 의 클래스 사용하기

세계의끝 — Sun, 05 Jul 2009 09:43:19 +0000

이 문제는 AS3.0 의 swf 간 로드 구조를 구성할 때 반드시 한번은 만나게 되는 문제이므로 정리해 둡니다.

Main.swf 에서 Sub.swf 를 Loader 를 이용해 로드한 후에 Main.swf 에서 Sub.swf 의 클래스나 메서드를 사용해야 할 때가 있습니다.

AS2.0 라면 MovieClipLoader 와 loadClip 을 이용하여 로드 완료 이벤트를 확인 한 후 인스턴스네임으로 참조해 들어가면 되지만, AS3.0의 경우에는 그런 방법으로 다른 swf의 클래스를 사용할수 없습니다. 이런 경우 ApplicationDomain 클래스의 getDefinition() 메서드를 이용해 참조해야 합니다.

이 예제에는 3개의 클래스가 사용됩니다. 각 클래스에 대한 설명은 본문과 코드 주석에 포함되어 있습니다.

// SubSystem.as 의 내용.
package
{
	import flash.display.Sprite
 
	/*
	 * 이 클래스는 별도로 SubSystem.swf로 컴파일 하여 Main.swf 에서 Loader를 통해 로드하는 대상으로 삼음
	 * 즉, 이 클래스는 SubSystem.swf 의 도큐먼트 클래스 입니다.
	 */
	public class SubSystem extends Sprite
	{
		public function SubSystem()
		{
			trace( "SubSystem !!!" )
		}
 
		public function createItem( $name:String = "" ):Sprite
		{
			var item:Circle = new Circle( $name, 50, 50 );
			addChild( item )
			return item;
		}
	}
}

생성자에서는 제대로 로드가 되었는지 확인하는 용도의 trace 외에는 하는 일이 없고, public 으로 공개된 createItem() 메서드는 Circle 클래스를 new 해주고, 객체를 반환하고 있습니다.

Circle 클래스는 예제용으로 밖에 사용할 일이 없는 궁극의 원그리기 클래스 입니다.

// Circle.as 의 내용.
package
{
	import flash.display.Sprite
 
	public class Circle extends Sprite
	{
		private var _name:String;
 
		public function Circle( $name:String = null, $x:int = 0, $y:int = 0, $radius:uint = 50, $color:uint = 0x000000, $alpha:Number = 1 )
		{
			draw( $x, $y, $radius, $color, $alpha )
			this._name = $name
		}
		private function draw( $x:int, $y:int, $radius:uint, $color:uint, $alpha:Number ):Sprite
		{
			var item:Sprite = new Sprite();
			item.graphics.beginFill( $color, $alpha );
			item.graphics.drawCircle( $x, $y, $radius );
 
			addChild( item )
			return item
		}
 
		override public function get name():String { return _name; }
	}
}

SubSystem 클래스에서 Circle 클래스를 따로 import 하지 않았으므로, 이 두개의 클래스는 같은 폴더에 넣어야 동작하겠군요.

다음은 Main 클래스 입니다. 이 파일은 Main.swf 에 사용되는 도큐먼트 클래스 입니다.

//Main.as 의 내용.
package
{
	import flash.display.DisplayObject;
	import flash.display.Loader;
	import flash.display.Sprite;
	import flash.events.Event;
	import flash.net.URLRequest;
 
	public class Main extends Sprite
	{
		private var loader:Loader = new Loader();
		private var request:URLRequest = new URLRequest( "SubSystem.swf" );
 
		public function Main()
		{
			//Loader는 직접 addEventListener 하지 못하고 contentLoaderInfo 를 통하여야 함
			loader.contentLoaderInfo.addEventListener( Event.COMPLETE, completeHandler );
			loader.load( request );
		}
 
		private function completeHandler( e:Event ):void
		{
			var runtimeClassRef:Class = loader.contentLoaderInfo.applicationDomain.getDefinition( "SubSystem" )  as  Class;
			var displayObj:DisplayObject = new runtimeClassRef(); //addChild 하려면 DisplayObject 로 캐스팅
			addChild( displayObj );
 
			var subSystemObj:Object = displayObj as Object; //메서드를 호출하려면 다시 Object 로 캐스팅
			var item1:Sprite = subSystemObj.createItem( "item1" );
			var item2:Sprite = subSystemObj.createItem( "item2" );
			item2.x = 100;
 
			//로드한 SubSystem.swf 의 자원은 이제 subSystemObj 로 참조하면 됩니다.
			trace( "subSystemObj.numChildren : ", subSystemObj.numChildren );
		}
	}
}

getDefinition() 과는 직접 관련은 없지만, 한가지 짚고 넘어가야할 내용이 있습니다. Loader 의 다운로드 진행상황이나 로드 완료 등의 이벤트를 받고 싶을 경우 Loader 에 contentLoaderInfo 를 통해 addEventListener 를 걸어야 합니다.^[01] Loader 에 직접 addEventListener 를 걸고 아무리 기다려본들 이벤트는 발생하지 않습니다.^[02]

다시 내용으로 돌아와서, Main.as 는 SubSystem.swf 를 Loader 를 통해 로드하고, 로드 완료된 이벤트 확인한 이후, SubSystem 의 내부 메서드를 호출하여 SubSystem 로 하여금 Circle 객체를 new 로 생성하게 하고 있습니다.

만약 SubSystem.swf 를 통해 얻고 싶은 것이 fla의 라이브러리에 Class 네임으로 정의한^[03] 무비클립이라면 getDefinition( “ClassName” ) 과 같이 해당 무비클립의 클래스 네임을 넣어주고 addChild 까지만 해주면 됩니다. 메서드 호출 까지도 필요 하지 않은 경우라면 이렇게 훨씬 더 간단하죠.

참고 : Main.swf 가 AS3.0 이고 SubSystem.swf 가 AS2.0 인 경우 ApplicationDomain 은 사용할 수 없습니다.

* 다른 swf 가 아닌 하나의 swf에서 fla 라이브러리에 정의한 클래스 이름으로 무비클립을 사용하려면 “AS3.0 getDefinitionByName() 메서드를 이용한 라이브러리 자원 이용 – AS2.0 attachMovie 대응” 을 읽어보세요..

로더객체.contentLoaderInfo.addEventListener(……)
로더객체.addEventListener(……) <– (잘못된 사용)
AS2.0의 Linkage 사용하듯

세계의끝과 플래시 원더랜드 » getDefinition

AS3.0 로더(Loader)로 불러온 다른 swf 의 클래스 사용하기