세계의끝과 플래시 원더랜드

/*****각 기능 실행*****/
//dmb 실행
ext_fscommand2("PLATFORM", "executeApp", "dmb");
 
//동영상 플레이어 실행
ext_fscommand2("PLATFORM", "executeApp", "movie");
 
//뮤직플레이어(mp3) 실행
ext_fscommand2("PLATFORM", "executeApp", "music");
 
//라디오 실행
ext_fscommand2("PLATFORM", "executeApp", "radio");
 
//게임 브라우져 실행
ext_fscommand2("PLATFORM", "executeApp", "game");
 
//사전 실행
ext_fscommand2("PLATFORM", "executeApp", "dic");
 
//포토뷰어 실행
ext_fscommand2("PLATFORM", "executeApp", "photo");
 
//보이스레코더 실행
ext_fscommand2("PLATFORM", "executeApp", "voicerec");
 
//텍스트 뷰어 실행
ext_fscommand2("PLATFORM", "executeApp", "text");
 
//setting 메뉴 실행
ext_fscommand2("PLATFORM", "executeApp", "setting");
 
 
 
/*****M35T 기기 상태 체크*****/
//배터리 상태수준을 가져와 battery 변수에 저장
ext_fscommand2("PLATFORM","getBatteryLevel", "battery");
 
//LCD상태가 잠겨 있는지 여부를 가져온 후 lcdlocked 변수에 저장, lcdlocked = 0 잠기지 않은 상태, lcdlocked = 1 잠긴상태
ext_fscommand2("PLATFORM","isLCDLocked","lcdlocked");
 
//micro SD 카드의 상태를 가져와 sdcard 변수에 저장, sdcard = 0 없음, sdcard = 1 있음
ext_fscommand2("PLATFORM","isExistSDCard","sdcard");
 
 
 
/*****swf 파일 로드*****/
//메인 UI 상태에서 다른 swf을 호출하고 메인 UI는 메모리에서 삭제.   
ext_fscommand2("PLATFORM", "excuteFlash", "C:\\Config\\test.swf");
 
//다른 swf 가 불러와 있는 상태에서 메인 UI로 돌아간다   
ext_fscommand2("PLATFORM", "runMainMenu");

/************************************************
//Meritech M35Touch Main UI Development & Design
//메리테크 M35Touch 메인 UI 개발, 디자인
//Slide type Flash User Interface
//슬라이드 타입 플래시 유저 인터페이스
//제작자 : 세계의끝(원종선)
//http://www.ufx.kr/blog
//cuebrick@naver.com (UI 수정에 대한 메일 문의는 답변해드리지 않습니다. 홈페이지의 블로그를 이용해주십시오.)
*************************************************/
 
//fscommand 의 _param 에 들어갈 각 기능 호출 String이 들어 있는 배열 (펌웨어에 지정되어 있는 명령어 이름)
//*****중요 : 이 배열의 순서(=명령어의 순서)를 바꾸려면 라이브러리에 있는 icon_mc 의 프레임 순서도 동일하게 변경해야 합니다. (그래야 명령어와 아이콘 그림이 일치)
var command_array:Array = [
			"dmb",
			"movie",
			"music",
			"radio",
			"game",
			"dic",
			"photo",
			"voicerec",
			"text",
			"setting"
			];
 
//핵심 함수 - fscommand 실행 함수 (M35T에게 명령을 내리는 부분)
function getExec (fid:Number){
	//배열의 명령어를 fid 의 파라미터를 이용해 로컬 변수에 저장
	var _param:String = command_array[fid];
 
	//M35T 에 명령을 내리는 부분
	ext_fscommand2("PLATFORM", "executeApp", _param);	
 
	//실제 명령어가 찍히는 모습을 확인
	//trace(fid +" : "+ _param)
}
 
//M35T 상태체크를 위한 setInterval 과 변수
var batteryCheckTime:Number = 1000;//배터리 체크 타임 1000 = 1초
var batteryID:Number = setInterval(getM35Tstat, batteryCheckTime)
var id_cnt:Number = 0;
var battery;
var lcdlocked;
var sdcard;
 
//M35T 상태체크
function getM35Tstat (){
	//배터리 상태수준을 가져와 battery 변수에 저장
	ext_fscommand2("PLATFORM","getBatteryLevel", "battery");
 
	//LCD상태가 잠겨 있는지 여부를 가져온 후 lcdlocked 변수에 저장, lcdlocked = 0 잠기지 않은 상태, lcdlocked = 1 잠긴상태
	ext_fscommand2("PLATFORM","isLCDLocked","lcdlocked");
 
	//micro SD 카드의 상태를 가져와 sdcard 변수에 저장
	ext_fscommand2("PLATFORM","isExistSDCard","sdcard");
 
	//sd카드의 상태 변수에 따라 아이콘 표시
	sdcard_mc.gotoAndStop(Number(sdcard) + 1);
 
	//기기 상태체크 초기 3번 이후에 메모리 확보를 위한 clearInterval
	if (id_cnt >= 3) {
		clearInterval(batteryID);
	}
	id_cnt++;
}
 
//M35T로부터 이벤트가 발생하면 해당 동작을 화면에 표시합니다
//화면에 표시하는 것만을 담당하는 부분입니다. 이것으로 기능을 제어할수는 없습니다
//이미 발생해 있는 상태는 체크되지 않습니다. (이미 발생해 있는 기기 상태는 getM35Tstat() 함수로 체크합니다)
messageEvent = new Object();
messageEvent.onEvent = function() {
	if (arguments[0] == "STAT_EVENT_BATTERY") {
		//배터리 레벨표시 아이콘 프레임 변경, arguments[1] = 0~4 까지
		battery_mc.gotoAndStop(arguments[1])
	} else if(arguments[0] == "STAT_EVENT_LCDLOCKED") {
		//화면 잠김 애니메이션 추가 arguments[1] = 0: 잠기지 않은 상태, 1: 잠긴 상태
		lock_mc.gotoAndStop(Number(arguments[1])+1)
	} else if(arguments[0] == "STAT_EVENT_SDCARD") {
		//sd card 있음 없음 표시 아이콘 추가, arguments[1] = 0: sd 없음, 1: sd 있음
		sdcard_mc.gotoAndStop(Number(arguments[1])+1)
	} else {
		outputDebugMsg("Unkown Event Error");
	}
}
ExtendedEvents.OnM35TPlatformEvent.addListener(messageEvent);